plugins {
    kotlin("jvm")
    `java-gradle-plugin`
    `maven-publish`
}

group = "com.xuqm.bugcollect"

val pluginVersion: String by lazy {
    (project.findProperty("SDK_BUGCOLLECT_VERSION") as? String)?.takeIf { it.isNotBlank() }
        ?: (project.findProperty("PUBLISH_VERSION") as? String)?.takeIf { it.isNotBlank() }
        ?: "0.0.1-SNAPSHOT"
}

version = pluginVersion

java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

kotlin {
    jvmToolchain(21)
}

gradlePlugin {
    plugins {
        create("bugcollect") {
            id = "com.xuqm.bugcollect"
            implementationClass = "com.xuqm.sdk.bugcollect.gradle.XuqmBugCollectPlugin"
            displayName = "XuqmGroup BugCollect Plugin"
            description = "Uploads ProGuard mapping files to the XuqmGroup BugCollect service after minified builds."
        }
    }
}

dependencies {
    compileOnly("com.android.tools.build:gradle:9.1.0")
}

publishing {
    repositories {
        maven {
            url = uri(rootProject.ext["nexusUrl"] as String)
            credentials {
                username = project.findProperty("NEXUS_USER") as? String ?: ""
                password = project.findProperty("NEXUS_PASSWORD") as? String ?: ""
            }
        }
    }
}